如何使用VBS修改二進(jìn)制文件HEX數(shù)據(jù)-創(chuàng)新互聯(lián)

這篇文章給大家分享的是有關(guān)如何使用VBS修改二進(jìn)制文件HEX數(shù)據(jù)的內(nèi)容。小編覺得挺實(shí)用的，因此分享給大家做個(gè)參考，一起跟隨小編過來看看吧。

企業(yè)建站必須是能夠以充分展現(xiàn)企業(yè)形象為主要目的，是企業(yè)文化與產(chǎn)品對(duì)外擴(kuò)展宣傳的重要窗口，一個(gè)合格的網(wǎng)站不僅僅能為公司帶來巨大的互聯(lián)網(wǎng)上的收集和信息發(fā)布平臺(tái)，創(chuàng)新互聯(lián)建站面向各種領(lǐng)域：水電改造等網(wǎng)站設(shè)計(jì)、成都全網(wǎng)營(yíng)銷推廣解決方案、網(wǎng)站設(shè)計(jì)等建站排名服務(wù)。

可用之處還是有的，如：隱藏快捷方式中目標(biāo)文件位置；破解XP中TCP/IP連接數(shù)限制；去掉RAR右鍵解壓菜單等等。

復(fù)制代碼 代碼如下:

Public BinaryData

If (lcase(right(wscript.fullname,11))="wscript.exe") Then
 WScript.Quit(0)
End If

If wscript.arguments.count<4 Then
 Wscript.Echo "Change File Hex. By: lxzzr  lxzzr@21cn.com"
 Wscript.Echo ""
 Wscript.Echo "Usage: cscript.exe " & WScript.ScriptName & " FilePath SavePath sHEX dHEX"
 Wscript.Echo "     : cscript.exe CHex.vbs "".\test.exe"" "".\new.exe"" ""80 7A 01 61"" ""80 7A 01 61"""
 WScript.Quit(0)
End If

sHEX = Replace(LCase(Wscript.Arguments(2)), " ", "")
dHEX = Replace(LCase(Wscript.Arguments(3)), " ", "")

Wscript.Echo "File: " & Wscript.Arguments(0)
Wscript.Echo "sHEX: " & Wscript.Arguments(2)
Wscript.Echo "dHEX: " & Wscript.Arguments(3)

ReadBinary(Wscript.Arguments(0))

MyData = Replace(BinaryData, sHEX, dHEX)

WriteBinary Wscript.Arguments(1), MyData

Wscript.Echo "All done."
Wscript.Quit(0)

Function ReadBinary(FileName)
 Dim Stream, ObjXML, MyNode

 Set ObjXML = CreateObject("Microsoft.XMLDOM")
 Set MyNode = ObjXML.CreateElement("binary")
 Set Stream = CreateObject("ADODB.Stream")

 MyNode.DataType = "bin.hex"

 Stream.Type = 1
 Stream.Open
 Stream.LoadFromFile FileName

 MyNode.NodeTypedValue = Stream.Read

 Stream.Close

 BinaryData = MyNode.Text

 Set MyNode = Nothing
 Set Stream = Nothing
 Set ObjXML = Nothing
End Function

Function WriteBinary(FileName, BufferData)
 Dim Stream, ObjXML, MyNode

 Set ObjXML = CreateObject("Microsoft.XMLDOM")
 Set MyNode = ObjXML.CreateElement("binary")
 Set Stream = CreateObject("ADODB.Stream")

 MyNode.DataType = "bin.hex"
 MyNode.Text = BufferData

 Stream.Type = 1
 Stream.Open
 Stream.Write MyNode.NodeTypedValue
 Stream.SaveToFile FileName, 2
 Stream.Close

 Set stream = Nothing
 Set MyNode = Nothing
 Set ObjXML = Nothing
End Function

感謝各位的閱讀！關(guān)于“如何使用VBS修改二進(jìn)制文件HEX數(shù)據(jù)”這篇文章就分享到這里了，希望以上內(nèi)容可以對(duì)大家有一定的幫助，讓大家可以學(xué)到更多知識(shí)，如果覺得文章不錯(cuò)，可以把它分享出去讓更多的人看到吧！

網(wǎng)頁標(biāo)題：如何使用VBS修改二進(jìn)制文件HEX數(shù)據(jù)-創(chuàng)新互聯(lián)
URL分享：http://m.kartarina.com/article20/ejcjo.html

成都網(wǎng)站建設(shè)公司_創(chuàng)新互聯(lián)，為您提供網(wǎng)站排名、小程序開發(fā)、網(wǎng)站設(shè)計(jì)公司、網(wǎng)頁設(shè)計(jì)公司、網(wǎng)站導(dǎo)航、品牌網(wǎng)站設(shè)計(jì)

廣告

聲明：本網(wǎng)站發(fā)布的內(nèi)容（圖片、視頻和文字）以用戶投稿、用戶轉(zhuǎn)載內(nèi)容為主，如果涉及侵權(quán)請(qǐng)盡快告知，我們將會(huì)在第一時(shí)間刪除。文章觀點(diǎn)不代表本網(wǎng)站立場(chǎng)，如需處理請(qǐng)聯(lián)系客服。電話：028-86922220；郵箱：631063699@qq.com。內(nèi)容未經(jīng)允許不得轉(zhuǎn)載，或轉(zhuǎn)載時(shí)需注明來源： 創(chuàng)新互聯(lián)